/** 
  Description: A Rubics Cube
  Object Name: Rubic_Cube
  Sub-parts  : Part, Label
  Textures   : Part_Texture, Label_Texture
  Position   : Center of cube is at origin
  Requires   : colors.inc
  Comments   : Alter A to affect roundiness of cubes.
               Alter B to change no. blocks in cube.
**/

#declare A=0.15
#declare B = -1

#declare Label=intersection{
  superellipsoid{<A,A>}
  box{<-1,-1,-0.05><1,1,0.05>} // Label Thickness
  scale 0.7                    // Label Size 
}

#declare Piece=object{
  superellipsoid{<A,A>}
  texture{
    pigment { color rgb<0.3,0.3,0.3> }
    finish { phong 1 ambient 0.3}
  }
}

// The top layer
#declare Rubic_Three =union{
  #declare Count = B
  #while (Count <abs(B)+1)
    object { Piece translate x*Count*2 }
    #declare Count= Count+1
  #end
}

#declare Rubic_Layer = union{
  #declare Count = B
  #while (Count<abs(B)+1)
    object { Rubic_Three translate z*Count*2 }
    #declare Count= Count+1
  #end
}

#declare Label_Edge=union{
  #declare Count = B
  #while (Count<abs(B)+1)
    object { Label translate x*Count*2}
    #declare Count= Count+1
  #end

}

#declare Label_End_Set=union{
  #declare Count = B
  #while (Count<abs(B)+1)
    object { Label_Edge rotate x*90 translate -z*Count*2 }
    #declare Count= Count+1
  #end
  pigment { color Yellow }
  finish{ reflection 0.05 }
}

#declare Label_Edge_Set=union{
  object { Label_Edge 
    pigment{ color Red } 
    finish{ reflection 0.05 }
    translate -z*3 }
  object { Label_Edge 
    pigment{ color Blue } 
    finish{ reflection 0.05 }
    translate -z*3 rotate y*90}
  object { Label_Edge 
    pigment{ color Green } 
    finish{ reflection 0.05 }
    translate -z*3 rotate y*180}
  object { Label_Edge 
    pigment{ color White } 
    finish{ reflection 0.05 }
    translate -z*3 rotate -y*90}
}

#declare Rubic_Mid=union{
  object { Rubic_Layer }
  object { Label_Edge_Set }
}

#declare Rubic_Top=union{
  object { Rubic_Layer }
  object { Label_End_Set  translate y}
  object { Label_Edge_Set}

}

#declare Rubic_Cube = union{
  #declare Count = B
  object { Rubic_Top translate y*Count*2 }
  #declare Count= Count+1
  #while (Count<abs(B))
    object { Rubic_Mid translate y*Count*2 }
    #declare Count= Count+1
  #end
  object { Rubic_Top translate y*Count*2 }
}